(*
Automate NZB Drop to Monitor a Folder.  You will be able to drag files into a folder
and NZB Drop will monitor this folder and begin processing any .NZB files that are
dropped there.  This allows you to drag an .NZB to a shared drive on another computer
and it will start downloading automatically without you having to use remote desktop.

Installation Instructions:

1. CTRL+Click on any Folder, go to "More" and select "Configure Folder Actions"

2. Check the box that says "Enable Folder Actios"

3. In the left panel, add a new folder and then browser to the folder you want to use
   as your drop location.  Once you choose the folder you will be promted to 
   select a script to attach.  Choose the "add - new item alert.scpt"
   
4. In the right panel, hightlight the new script and click "Edit"

5. When Script Editor opens, replace the entire contents of the script
   with this code (that you reading now).  Save the script and it 
   will re-compile and update.  If you are prompted to overwrite anything,
   just say Yes.
   
   
That's it - now try dragging an .NZB file into this folder.  You should see
an alert pop up asking if you want to automatically process the NZB.  If you
do nothing, it will automatically start uploading after 5 seconds.

Credits: Jason Hinkle http://www.verysimple.com/
         This code is provided AS-IS, use at your own risk.
		 This code was descended from Apple Sample Code.
*)

property dialog_timeout : 5 -- set the amount of time before dialogs auto-answer.

on adding folder items to this_folder after receiving added_items
	try
		tell application "Finder"
			--get the name of the folder
			set the folder_name to the name of this_folder
		end tell
		
		-- find out how many new items have been placed in the folder
		set the item_count to the number of items in the added_items
		--create the alert string
		set alert_message to ("Folder Actions Alert:" & return & return) as Unicode text
		if the item_count is greater than 1 then
			set alert_message to alert_message & (the item_count as text) & " new items have "
		else
			set alert_message to alert_message & "One new item has "
		end if
		set alert_message to alert_message & "been placed in folder " & «data utxt201C» & the folder_name & «data utxt201D» & "."
		set the alert_message to (the alert_message & return & return & "Would you like to automatically process them?")
		
		display dialog the alert_message buttons {"Yes", "No"} default button 1 with icon 1 giving up after dialog_timeout
		set the user_choice to the button returned of the result
		
		if user_choice is not "No" then
			tell application "NZB Drop"
				--go to the desktop 
				activate
				--open the folder
				open the added_items
			end tell
		end if
	end try
end adding folder items to